Maximaで学ぶ３乗根を含む分数の有理化

数学の具体的な計算にMaximaを使って、数学もMaximaも同時に学んでしまいましょう。今回はMaximaを使って３乗根を含む分数の有理化の計算をしてみたいと思います。２乗根を含む分数の有理化は高校数学でも取り扱いますが、３乗根を含んだ場合にはどのようにして有理化できるのでしょうか？ここではある数の３乗根を含む分数の有理化の公式を与えます。実は、その背後には方程式が代数的に解けるかどうかに関わる「ガロア理論」に関係する構造が潜んでいたりします。計算自体はシンプルなものですが、手計算では少々面倒で、計算機の便利さが実感できる題材だと思います。

２乗根を含む分数の有理化
３乗根を含む分数の有理化

２乗根を含む分数の有理化

まずウォーミングアップとして２乗根を含む分数の有理化を復習しましよう。実数

$\qquad\displaystyle{z=a\sqrt{n}+b}$

を与え、その逆数

$\qquad\displaystyle{\frac{1}{z}=\frac{1}{a\sqrt{n}+b}}$

を考えます。このとき、適当な因子を分母と分子に掛けて、分母に含まれる２乗根 $\sqrt{n}$ を消してしまおうというのが「分母の有理化」です。高校数学でも習ったように、この数 $1/z$ を有理化するには

$\qquad\displaystyle{\tau(z)=-a\sqrt{n}+b}$

を考え、これを分母と分子に掛け合わせます：

$\qquad\displaystyle{\begin{aligned}\frac{1}{z}&=\frac{\tau(z)}{z\tau(z)}\\&=\frac{-a\sqrt{n}+b}{(a\sqrt{n}+b)(-a\sqrt{n}+b)}\\&=\frac{-a\sqrt{n}+b}{-n^2a^2+b^2}\end{aligned}}$

これで分数が有理化されたことになります。

さて、上で写像 $\tau$ というのを考えていたことに注意しましょう。これは線形写像ですが、 $n$ の２乗根を

$\qquad\displaystyle{\tau(\sqrt{n})=-\sqrt{n}}$

にうつします。さて、これらの数 $\pm\sqrt{n}$ ですが、それは方程式

$\qquad\displaystyle{x^2=n}$

の２つの解に他なりません。つまり、写像 $\tau$ はこの方程式の２つの解を入れ換える操作に対応しています。

この写像 $\tau$ の重要な性質が以下の２つです。まず１つめは

$\qquad\displaystyle{\tau^2(z)=\tau(\tau(z))=z}$

となって、写像を２回合成すると恒等写像になるということです。２つめは、写像が四則演算を保っているということです。つまり $z_i=a_i\sqrt{n}+b_i \ (i=1,2)$ とすると

$\qquad\displaystyle{\begin{aligned}\tau(z_1+z_2)&=\tau(z_1)+\tau(z_2)\\ \tau(z_1-z_2)&=\tau(z_1)-\tau(z_2)\\ \tau(z_1z_2)&=\tau(z_1)\tau(z_2)\\ \tau\left(\frac{z_1}{z_2}\right)&=\frac{\tau(z_1)}{\tau(z_2)}\end{aligned}}$

が成り立ちます。これを実際に確かめてみます。まずは和と差です。

kill(all)$
z1: a1*s+b1$   /* ２乗根を s として表現しています */
z2: a2*s+b2$
t(z):=expand(ratcoeff(z,s,0)-ratcoeff(z,s,1)*s)$
is(t(z1+z2)=t(z1)+t(z2));
is(t(z1-z2)=t(z1)-t(z2));

次に積と商ですが、 $z_1$ と $z_2$ の積には $s^2=n$ という項が出現するのでこれを $n$ に置き換える必要があります：

Ev(z):=subst(n, s^2, expand(z))$
is(t(Ev(z1*z2))=Ev(t(z1)*t(z2)));

また、商は分母を有理化して、示すべき式を

$\qquad\displaystyle{\tau\left(\frac{z_1}{z_2}\right)=\tau\left(\frac{z_1\tau(z_2)}{z_2\tau(z_2)}\right)\overset{?}{=}\frac{\tau(z_1)z_2}{z_2\tau(z_2)}=\frac{\tau(z_1)}{\tau(z_2)}}$

と書き換えます：

lhs: t(Ev(z1*t(z2))/Ev(z2*t(z2)))$
rhs: Ev(t(z1)*z2)/Ev(z2*t(z2))$
factor(lhs-rhs);

以上により、写像 $\tau$ が四則演算を保つことがわかりました。

３乗根の話にいく前に、とても重要な考察を述べておきます。有理化の本質は、分母が２乗根を含まない形に変形することでした。そこでいま一度、有理化の手続きを見直してみます：

$\qquad\displaystyle{\frac{1}{z}=\frac{\tau(z)}{z\tau(z)}}$

右辺の分母に現れた $\zeta\equiv z\tau(z)$ という数ですが、これを写像 $\tau$ の性質を使って見直してみると

$\qquad\displaystyle{\tau(\zeta)=\tau(z\tau(z))=\tau(z)\tau^2(z)=z\tau(z)=\zeta}$

というように、写像 $\tau$ の作用に対して不変な組み合わせになっている、つまり２乗根を含まない形になっていることがわかります。少しまだるっこしいようですが、このような性質を見定めてその背後にある構造を見抜くことが、３乗根あるいは一般の累乗根を有理化するための補助線になります。

３乗根を含む分数の有理化

さて、それでは３乗根を含む分数の有理化に挑みます。そこで実数

$\qquad\displaystyle{z=pn^{2/3}+qn^{1/3}+r}$

を考え、その逆数

$\qquad\displaystyle{\frac{1}{z}=\frac{1}{pn^{2/3}+qn^{1/3}+r}}$

の分母から３乗根を消すための因子を求めてみます。このとき、２乗根の場合と同様に方程式

$\qquad\displaystyle{x^3=n}$

の解を考えましょう。これは３次方程式なので、解は３つあります。実際

$\qquad\displaystyle{x=n^{1/3},\quad n^{1/3}\omega,\quad n^{1/3}\omega^2}$

が解になります。ただし $\omega$ は１の３乗根で

$\qquad\displaystyle{\omega=e^{i\frac{2\pi}{3}}=\cos\frac{2\pi}{3}+i\sin\frac{2\pi}{3}=\frac{-1+i\sqrt{3}}{2}}$

であり $\omega^3=1$ を満たします。Maximaで確かめると

kill(all)$
assume(n>0)$
solve(x^3=n, x);
w: cos(2*%pi/3)+%i*sin(2*%pi/3);
expand(w^2);
expand(w^3);

です。

さて、２乗根の場合にやったように、上の方程式の解を入れ替える写像を考えてみたいわけですが、３つの対象を入れ替えるわけですから３次対称群の作用が考えられます。つまり３つの対象から１つを固定して残りの２つを入れ替える置換の操作が３つと、（恒等変換を含めた）巡回置換の操作が３つの、計６つの操作からなる群です。しかしここで注意しないといけないのは、これらの解の入れ替え $\varphi$ は勝手にやっていいわけではなく、四則演算の操作と両立しなければいけないということです。つまり

$\qquad\displaystyle{\begin{aligned}\varphi(z_1+z_2)&=\varphi(z_1)+\varphi(z_2)\\ \varphi(z_1-z_2)&=\varphi(z_1)-\varphi(z_2)\\ \varphi(z_1z_2)&=\varphi(z_1)\varphi(z_2)\\ \varphi\left(\frac{z_1}{z_2}\right)&=\frac{\varphi(z_1)}{\varphi(z_2)}\end{aligned}}$

を満たさないといけません。たとえば

$\qquad\displaystyle{\begin{aligned}\varphi(n^{1/3})&=n^{1/3}\omega\\ \varphi(n^{1/3}\omega)&=n^{1/3}\\ \varphi(n^{1/3}\omega^2)&=n^{1/3}\omega^2\end{aligned}}$

という置換を考えると、 $n^{1/3}\omega=\omega\cdot n^{1/3}\overset{\varphi}{\rightarrow} \omega\cdot n^{1/3}\omega=n^{1/3}\omega^2$ となるはずですが、これでは定義の第２番目の式と矛盾してしまいます。つまり $\varphi(z_1z_2)=\varphi(z_1)\varphi(z_2)$ （いまの場合 $z_1=\omega, \ z_2=n^{1/3}$ ）が成り立ちません。

結局、四則演算との無矛盾性から、２つだけを入れ替えるという置換は不適当であることがわかります。そこでいま解の巡回置換

$\qquad\displaystyle{\sigma:\quad n^{1/3}\rightarrow n^{1/3}\omega\rightarrow n^{1/3}\omega^2\rightarrow n^{1/3}}$

として写像 $\sigma$ を定義します。すると

$\qquad\displaystyle{\sigma(pn^{2/3}+qn^{1/3}+r)=pn^{2/3}\omega^2+qn^{1/3}\omega+r}$

また、その合成は（ $\omega^3=1$ であることを用いると矛盾なく計算できて）

$\qquad\displaystyle{\begin{aligned}\sigma^2(pn^{2/3}+qn^{1/3}+r)&=pn^{2/3}\omega^4+qn^{1/3}\omega^2+r\\&=pn^{2/3}\omega+qn^{1/3}\omega^2+r\end{aligned}}$

を与えます。さらにもう一度写像を合成すると

$\qquad\displaystyle{\begin{aligned}\sigma^3(pn^{2/3}+qn^{1/3}+r)&=pn^{2/3}\omega^3+qn^{1/3}\omega^3+r\\&=pn^{2/3}+qn^{1/3}+r\end{aligned}}$

となって恒等写像を与えます。以上の性質から、有理化の因子として

$\qquad\displaystyle{\frac{1}{z}=\frac{\sigma(z)\sigma^2(z)}{z\sigma(z)\sigma^2(z)}}$

を考えると、右辺の分母の組み合わせ $\zeta=z\sigma(z)\sigma^2(z)$ が写像 $\sigma$ のもとで不変である、つまり３乗根を含まない形になっていることがわかります。

最後に、３乗根を含む分母の有理化の公式を与えておきましょう：

$\qquad\displaystyle{\frac{1}{pn^{2/3}+qn^{1/3}+r}=\frac{(q^2-pr)n^{2/3}+(np^2-qr)n^{1/3}+(r^2-npq)}{n^2p^3+(q^3-3pqr)n+r^3}}$

これはMaximaを使って以下のようにして求めました。

kill(all)$
s(f):=ratcoeff(f,t,0)*t^0+ratcoeff(f,t,1)*t^1*w+ratcoeff(f,t,2)*t^2*w^2$
z: p*t^2+q*t+r$   /* ここでは３乗根を t として記号化し、３乗根の次数をカウントしています */
Den: rat(subst( (sqrt(3)*%i-1)/2, w, z*s(z)*s(s(z)) ))$
D: subst(n^2, t^6, subst(n, t^3, expand(Den)))$
Num: rat(subst( (sqrt(3)*%i-1)/2, w, s(z)*s(s(z)) ))$
N: subst(n^2, t^6, subst(n, t^3, expand(Num)))$
N/D;

本記事で取り扱った計算を、４乗根、５乗根、…と拡張してみるのも良い練習問題になると思います。

キーワード：Maxima、累乗根、有理化、代数学、方程式

pianofisica

Mathematics & Physics, Maxima, a bit Python & Wolfram, and Arts

Maximaで学ぶ３乗根を含む分数の有理化

２乗根を含む分数の有理化

３乗根を含む分数の有理化