物理学の具体的な計算にMaximaを使って、物理学もMaximaも同時に学んでしまいましょう。
今回はMaximaを使ってシュレーディンガー方程式を解いてみたいと思います。
この記事で取り上げるのは1次元調和振動子の問題です。
Maximaのごく基本的な使い方については以下の記事を参照してください:
正準交換関係
まず前提として、量子力学では古典的な物理量にはエルミート演算子が対応します。
とくに質点の位置座標と運動量に対応する演算子、位置演算子 と運動量演算子 は
次の正準交換関係をみたします。
ここに角括弧は交換子で、2つの演算子 と に対して
と定義します。
1次元空間の波動関数 に対しては位置演算子 と運動量演算子 は
と作用するものと定義します。
実際、このように演算子の作用を定義すると、 の任意のなめらかな関数 に対して
となり、 の関数の空間の上で確かに交換関係が成り立っていることがわかります。
この計算自体は難しいものではないですが、
これはMaximaでは以下のようにして計算できます。
kill(all)$ declare(h,constant)$ /* プランク定数 */ depends(F,x)$ /* x に依存する任意関数 */ X(f):=x*f$ /* 演算子 x の関数への作用 */ P(f):=-%i*h*diff(f,x,1)$ /* 演算子 p の関数への作用 */ expand(X(P(F))-P(X(F))); /* 交換子 */
1次元調和振動子のハミルトニアン
で与えられます。ここで は質点の質量、 はバネ定数です。いま
とすればハミルトニアンは
と書き直されます。
ハミルトン形式による古典的な運動の定式化では、
物理量 に対する時間発展は
で与えられます。ここで波括弧はポアソン括弧で
によって定義されます。
したがって、とくに質点の位置座標 と運動量 の時間発展は
ですが、2つの式から運動量 を消去すれば
さて、ハミルトニアンが物理量の二乗の和になっていることから、因数分解して
と書き表してみましょう。
生成・消滅演算子
ハミルトニアンを上のように因数分解した形から、生成・消滅演算子をそれぞれ
と定義してみます。するとこれらの交換関係が
と計算されます。実際、Maximaで計算すると
declare([m,w],constant)$ a(f):=(sqrt(m*w/(2*h))*X(f)+%i/sqrt(2*h*m*w)*P(f))$ ad(f):=(sqrt(m*w/(2*h))*X(f)-%i/sqrt(2*h*m*w)*P(f))$ radcan(a(ad(F))-ad(a(F)));
より、確かに上の交換関係が成り立っています。
エネルギー固有値
各項の積の順序に注意しながら書き直すと
がわかります。
となる非自明な関数として決めます。
より、その固有値は であることがわかります。
またこの波動関数 から、
ハミルトニアンの固有状態が以下のようにして構成できます:
ここで は規格化のための定数で、規格化条件
によって決めます。
このように構成した関数 に対してハミルトニアンを作用させると
となります。最後の等式では の性質を使いました。
さて、交換子 ですが、これは
と計算されます。 の場合はすでに計算しました。
ある自然数 まで上記の公式が成り立っていると仮定します。
ここで公式
を使うと の場合に対して
となり、公式の成立が示されます。
ハミルトニアンの への作用に話を戻すと
となって、 がハミルトニアンの固有状態で、
その固有値が であることがわかります。
基底状態の波動関数の具体形
記号を簡単化するために、以下のようにして変数を無次元化します。
すると消滅演算子は
と表されます。したがって基底状態の波動関数 に対する方程式は
となります。これは1階線形微分方程式なので簡単に解がわかります:
もとの変数 で書き表すと
です。規格化条件から、位相因子 の不定性を除いて
と決まります。実際
declare(theta,constant)$ assume(h>0,m>0,w>0)$ psi0:exp(%i*theta)*((m*w)/(%pi*h))^(1/4)*exp(-m*w*x^2/(2*h))$ integrate(psi0*conjugate(psi0),x,-inf,inf);
より、たしかに規格化されています。
励起状態の波動関数の具体形
基底状態に次々と生成演算子を作用させて励起状態が得られるので、
いくつか具体的に見てみましょう。
以下、物理的でない規格化の位相因子は1とします。
kill(psi0)$ psi0:((m*w)/(%pi*h))^(1/4)*exp(-m*w*x^2/(2*h))$
psi1:radcan(C1*ad(psi0))$ solve(integrate(psi1*conjugate(psi1),x,-inf,inf)=1, C1); psi1:subst(rhs(%[2]), C1, psi1);
psi2:radcan(C2*ad(psi1))$ solve(integrate(psi2*conjugate(psi2),x,-inf,inf)=1, C2); psi2:subst(rhs(%[2]), C2, psi2);
psi3:radcan(C3*ad(psi2))$ solve(integrate(psi3*conjugate(psi3),x,-inf,inf)=1, C3); psi3:subst(rhs(%[2]), C3, psi3);
より
などと求まります。あるいは無次元の変数 を使えば
と書き表せます。ここで特徴的な多項式が現れることに注意します。
じつは、1次元調和振動子のエネルギー固有関数は
以下で説明するエルミート多項式(Hermite polynoimal) を使って
と表すことができます。
エルミート多項式
エルミート多項式 は、Rodriguesの公式によって
として求まる多項式です。具体的にいくつかあげると、
makelist(expand(hermite(n,x)), n, 0, 7);
あるいは、具体的にRodoriguesの公式を使って
makelist(expand((-1)^n*exp(x^2)*diff(exp(-x^2),x,n)), n, 0, 7);
より(もちろん、どちらも同じ多項式を与えますが)
といった多項式です。エルミート多項式には次の公式があります:
この公式はRodriguesの公式を微分することで容易に示すことができます。
公式を使うと、生成演算子の作用のもとで
が成り立つことがわかります。
これにより、規格化定数を除いて が求まります。
また、規格化定数もエルミート多項式の性質
から決めることができます。この性質は具体的に
makelist(makelist( integrate(hermite(m,x)*hermite(n,x)*exp(-x^2),x,-inf,inf), n, 0, 7), m, 0, 7);
によって確かめることができます。
波動関数の図示
エネルギー固有状関数をいくつか図示してみましょう:
plot2d (makelist( hermite(n,x)*exp(-x^2/2)/(sqrt(2)^n*%pi^(1/4)*sqrt(n!)), n,0,3), [x, -5, 5])$
として出力されたのが次の図です:
ただし、、、 はいずれも1としています。
また、粒子の存在確率分布(波動関数の絶対値2乗) も図示してみると
plot2d (makelist( (hermite(n,x)*exp(-x^2/2)/(sqrt(2)^n*%pi^(1/4)*sqrt(n!)))^2, n,0,3), [x, -5, 5])$
により
と図示されます。
さいごに粒子の存在確率分布から、粒子が存在する位置の期待値と分散を求めてみます:
makelist(integrate( x*(hermite(n,x)*exp(-x^2/2)/(sqrt(2)^n*%pi^(1/4)*sqrt(n!)))^2, x, -inf, inf), n,0,10);
makelist(integrate( x^2*(hermite(n,x)*exp(-x^2/2)/(sqrt(2)^n*%pi^(1/4)*sqrt(n!)))^2, x, -inf, inf), n,0,10);
より、いずれの状態に対しても、
粒子が存在する位置の期待値 はゼロとなります。
このことは、波動関数の分布が原点に対して左右均等であることからもわかります。
しかし、分散はエネルギー固有値が大きくなるにつれて大きくなることがわかります。
このことは、波動関数の分布が高いエネルギーの状態になるにつれて、
原点からより離れた点にも分布のヤマをもつことからわかります。
以上、これらの計算結果は、図示した確率分布の様子と直感的にも整合します。