pianofisica

Mathematics & Physics, Maxima, a bit Python & Wolfram, and Arts

n次元時空のSchwarzschild解(Maximaによるテンソル計算)

物理の具体的な計算にMaximaを使って、物理もMaximaも同時に学んでしまいましょう。

今回はMaximaを使ってリーマン幾何学一般相対性理論の計算をしてみたいと思います。

具体的には、球対称で静的な場合のアインシュタイン方程式の解として知られる

de Sitter-Schwarzschild解とよばれる解をみてみます。

4次元の場合についてみたあと、5次元の場合についても同様にMaximaで計算してみます。

6次元の場合については結果だけ載せておきます。

Maximaのごく基本的な使い方については以下の記事を参照してください:

pianofisica.hatenablog.com



4次元のリーマン幾何

以下、同一式中で同じ文字の添字が現れた場合、

その添字については和をとるものとします(アインシュタインの規約)。

座標系の設定

4次元空間の座標

 \displaystyle{x^i=\left(\begin{array}{c} x_1 \\ x_2 \\ x_3 \\ x_4 \end{array} \right)}

Maximaでは

x:matrix([x1],[x2],[x3],[x4])$

と入力します。

計量テンソルの設定

上で導入した座標系  \{x^i\} に付随する空間の計量テンソル

 \displaystyle{g_{ij}=\left(\begin{array}{cccc} g_{11} & g_{12} & g_{13} & g_{14} \\ g_{21} & g_{22} & g_{23} & g_{24} \\ g_{31} & g_{32} & g_{33} & g_{34} \\ g_{41} & g_{42} & g_{43} & g_{44} \end{array} \right)}

Maximaに入力するには

g:matrix(  
[ g11, g12, g13, g14],
[ g21, g22, g23, g24],
[ g31, g32, g33, g34],
[ g41, g42, g43, g44])$

とします。 g^{ik}g_{kj}=\delta^i_j として導入される上付き添字の  g^{ij}

ginv:invert(g)$

で計算されます。

Christoffel記号

 \displaystyle{\Gamma^i_{jk}=\frac12g^{in}\left(\frac{\partial g_{nj}}{\partial x^k}+\frac{\partial g_{nk}}{\partial x^j}-\frac{\partial g_{jk}}{\partial x^n}\right)}

Gamma[i,j,k]:=sum(
1/2*ginv[i,n]*( diff(g[n,j],x[k,1]) + diff(g[n,k],x[j,1]) - diff(g[j,k],x[n,1]) ), n,1,4)$
Riemannの曲率テンソル

 \displaystyle{R^i_{jkl}=\frac{\partial\Gamma^i_{lj}}{\partial x^k}-\frac{\partial\Gamma^i_{kj}}{\partial x^l}+\Gamma^n_{lj}\Gamma^i_{kn}-\Gamma^n_{kj}\Gamma^i_{ln}}

R[i,j,k,l]:=
diff( Gamma[i,l,j], x[k,1]) - diff(Gamma[i,k,j], x[l,1]) 
+sum( Gamma[n,l,j]*Gamma[i,k,n] - Gamma[n,k,j]*Gamma[i,l,n], n,1,4)$

 


Ricciテンソル

 \displaystyle{R_{jk}=R^n_{jnk}}

Ricc[j,k]:=ratsimp(sum(R[n,j,n,k], n,1,4))$
Ricciスカラー

 \displaystyle{R=g^{jk}R_{jk}}

R: ratsimp(sum(sum(ginv[n,k]*Ricc[n,k],k,1,4), n, 1, 4))$
Einsteinテンソル

 \displaystyle{G_{ij}=R_{ij}-\frac12Rg_{ij}}

Ein[i,j]:=Ricc[i,j]-1/2*G[i,j]*R$
Einstein方程式

計量テンソル  g_{ij} を決定する基本方程式は、Einstein方程式

 \displaystyle{G_{ij}=0}

です。



4次元de Sitter-Schwarzschild解

具体的に計算するために、時間  t と3次元空間の極座標  (r,\theta,\varphi) からなる座標系

 \displaystyle{\left(\begin{array}{c} t \\ r \\ \theta \\ \varphi \end{array} \right)}

x:matrix([t],[r],[theta],[phi])$

で、静的で球対称な場合の

 \displaystyle{g_{ij}=\left(\begin{array}{cccc} g_{tt} & g_{tr} & g_{t\theta} & g_{t\varphi} \\ g_{rt} & g_{rr} & g_{r\theta} & g_{r\varphi} \\ g_{\theta t} & g_{\theta r} & g_{\theta\theta} & g_{\theta\varphi} \\ g_{\varphi t} & g_{\varphi r} & g_{\varphi\theta} & g_{\varphi\varphi} \end{array} \right)=\left(\begin{array}{cccc} -f(r) & 0 & 0 & 0 \\ 0 & \frac{1}{f(r)} & 0 & 0 \\ 0 & 0 & r^2 & 0 \\ 0 & 0 & 0 & r^2\sin^2\theta \end{array} \right)}

という形の計量テンソルを考えます:

depends(f, r)$
/* f が r の関数であることを宣言します */
g:matrix(  
[ -f, 0, 0, 0],
[ 0, f^(-1), 0, 0],
[ 0, 0, r^2, 0],
[ 0, 0, 0, r^2*sin(theta)^2]);

このとき、Christoffel記号、Riemann曲率テンソル、Ricciテンソル、Einsteinテンソル

ginv:invert(g)$
Gamma[i,j,k]:=sum(
1/2*ginv[i,n]*( diff(g[n,j],x[k,1]) + diff(g[n,k],x[j,1]) - diff(g[j,k],x[n,1]) ), n,1,4)$
R[i,j,k,l]:=
diff( Gamma[i,l,j], x[k,1]) - diff(Gamma[i,k,j], x[l,1]) 
+sum( Gamma[n,l,j]*Gamma[i,k,n] - Gamma[n,k,j]*Gamma[i,l,n], n,1,4)$
Ricc[j,k]:=ratsimp(sum(R[n,j,n,k], n,1,4))$
/* 式整理のために ratsimp(式の簡単化)を使っています */
R: ratsimp(sum(sum(ginv[n,k]*Ricc[n,k],k,1,4), n, 1, 4))$
/* 同上 */
Ein[i,j]:=factor(xthru(Ricc[i,j]-1/2*G[i,j]*R))$ 
/* 式整理のために factor(因子化)xthru(通分)を使っています */

で計算されます。Einsteinテンソルの計算結果を表示すると

matrix(
[Ricc[1,1],Ricc[1,2],Ricc[1,3],Ricc[1,4]],
[Ricc[2,1],Ricc[2,2],Ricc[2,3],Ricc[2,4]],
[Ricc[3,1],Ricc[3,2],Ricc[3,3],Ricc[3,4]],
[Ricc[4,1],Ricc[4,2],Ricc[4,3],Ricc[4,4]]);

より

 \displaystyle{G_{ij}=\left(\begin{array}{cccc} \frac{f(rf''+2f')}{2r} & 0 & 0 & 0 \\ 0 & -\frac{rf''+2f'}{2rf} & 0 & 0 \\ 0 & 0 & -rf'-f+1 & 0 \\ 0 & 0 & 0 & (-rf'-f+1)\sin^2\theta \end{array} \right)}

がわかります。ここで  f'=df/dr また  f''=d^2f/dr^2 とします。Einstein方程式

 G_{ij}=0

により

 rf''+2f'=0\\ -rf'-f+1=0

が要請されます。2つの式から  f に対する微分方程式

 r^2f''+2(1-f)=0

を得ます。その解は

depends(f, r)$ 
/* すでに上で宣言していますが、この部分だけを取り出しても動くように念のため書いておきます */
ode2( r^2*diff(f, r, 2)+2-2*f=0, f, r );
/* ode2( 2階常微分方程式,  未知関数,  変数 ) は微分方程式を解くためのコマンドです */

より

 \displaystyle{f(r)=1-\frac{a}{r}-br^2}

であることがわかります。ここで  a b は任意定数です。

とくに  b=0 の場合をSchwarzschild解といいます。

また、 a=0 の場合はde Sitter空間を記述します。

これらを重ね合わせた一般形はde Sitter-Schwarzschild解とよばれます。



5次元de Sitter-Schwarzschild解

5次元の場合に、時間  t と4次元空間の極座標  (r,\theta,\varphi,\psi) からなる座標系で

 \displaystyle{g_{ij}=\left(\begin{array}{ccccc} g_{tt} & g_{tr} & g_{t\theta} & g_{t\varphi} & g_{t\psi} \\ g_{rt} & g_{rr} & g_{r\theta} & g_{r\varphi} & g_{r\psi}\\ g_{\theta t} & g_{\theta r} & g_{\theta\theta} & g_{\theta\varphi} & g_{\theta\psi} \\ g_{\varphi t} & g_{\varphi r} & g_{\varphi\theta} & g_{\varphi\varphi} & g_{\varphi\psi} \\ g_{\psi t} & g_{\psi r} & g_{\psi\theta} & g_{\psi\varphi} & g_{\psi\psi} \end{array} \right)=\left(\begin{array}{ccccc} -f(r) & 0 & 0 & 0 & 0 \\ 0 & \frac{1}{f(r)} & 0 & 0 & 0 \\ 0 & 0 & r^2 & 0 & 0 \\ 0 & 0 & 0 & r^2\sin^2\theta &0 \\  0 & 0 & 0 &0 & r^2\sin^2\theta\sin^2\varphi \end{array} \right)}

として4次元の場合と同様に静的で球対称な場合を考えます。このとき

kill(all)$ x:matrix([t],[r],[theta],[phi],[psi]);
depends(f, r)$
g:matrix(  
[ -f, 0, 0, 0, 0],
[ 0, f^(-1), 0, 0, 0],
[ 0, 0, r^2, 0, 0],
[ 0, 0, 0, r^2*sin(theta)^2, 0],
[ 0, 0, 0, 0, r^2*sin(theta)^2*sin(phi)^2]);
ginv:invert(g)$
Gamma[i,j,k]:=sum(
1/2*ginv[i,n]*( diff(g[n,j],x[k,1])+diff(g[n,k],x[j,1])-diff(g[j,k],x[n,1]) ), n,1,5)$
R[i,j,k,l]:=diff( Gamma[i,l,j], x[k,1]) -diff(Gamma[i,k,j], x[l,1]) 
+sum( Gamma[n,l,j]*Gamma[i,k,n] - Gamma[n,k,j]*Gamma[i,l,n], n,1,5)$
Ricc[j,k]:=ratsimp(sum(R[n,j,n,k], n,1,5))$
R:ratsimp(sum(sum(ginv[n,k]*Ricc[n,k],k,1,5), n, 1, 5))$
Ein[i,j]:=trigsimp(factor(expand(Ricc[i,j]-1/2*g[i,j]*R)))$
/* 式整理のために trigsimp(三角関数の簡単化)factor(因子化)expand(展開)を使っています */
matrix(
[Ein[1,1],Ein[1,2],Ein[1,3],Ein[1,4],Ein[1,5]],
[Ein[2,1],Ein[2,2],Ein[2,3],Ein[2,4],Ein[2,5]],
[Ein[3,1],Ein[3,2],Ein[3,3],Ein[3,4],Ein[3,5]],
[Ein[4,1],Ein[4,2],Ein[4,3],Ein[4,4],Ein[4,5]],
[Ein[5,1],Ein[5,2],Ein[5,3],Ein[5,4],Ein[5,5]]);

より、Einsteinテンソル

 \displaystyle{G_{ij}=\left(\begin{array}{ccccc} -\frac{3f(rf'+2f-2)}{2r^2} & 0 & 0 & 0 & 0 \\ 0 & \frac{3(rf'+2f-2)}{2r^2f} & 0 & 0 &0 \\ 0 & 0 & \frac{r^2f''+4rf'+2f-2}{2} & 0 & 0 \\ 0 & 0 & 0 & \frac{r^2f''+4rf'+2f-2}{2}\sin^2\theta & 0 \\ 0 & 0 & 0 & 0 & \frac{r^2f''+4rf'+2f-2}{2}\sin^2\theta\sin^2\varphi \end{array} \right)}

がわかります。Einstein方程式  G_{ij}=0 より

 rf'+2f-2=0\\ r^2f''+4rf'+2f-2=0

が関数  f に課されます。これらの式を合わせて

 r^2f''+6(1-f)=0

という  f に関する微分方程式を得ることができます。その解は

exponentialize:true$ /* 双曲線関数(と三角関数)を指数関数で表すためのフラグです */
depends(f, r)$
expand(ode2( r^2*diff(f, r, 2)+6-6*f=0, f, r )); /* expand(展開)で結果の式を簡単化しました */

から

 \displaystyle{f(r)=1-\frac{a}{r^2}-br^3}

です。ここで  a b は任意定数です。

4次元の場合と同様に、 b=0 とした解

 \displaystyle{g_{ij}=\left(\begin{array}{ccccc} -\left(1-\frac{a}{r^2}\right) & 0 & 0 & 0 & 0 \\ 0 & \left(1-\frac{a}{r^2}\right)^{-1} & 0 & 0 & 0 \\ 0 & 0 & r^2 & 0 & 0 \\ 0 & 0 & 0 & r^2\sin^2\theta &0 \\  0 & 0 & 0 &0 & r^2\sin^2\theta\sin^2\varphi \end{array} \right)}

は5次元Schwarzschild解とよばれます。

6次元de Sitter-Schwarzschild解

6次元の場合に、時間  t と5次元空間の極座標  (r,\theta,\varphi,\psi,\chi) からなる座標系で

 \displaystyle{g_{ij}=\left(\begin{array}{cccccc} -f(r) & 0 & 0 & 0 & 0 & 0 \\ 0 & \frac{1}{f(r)} & 0 & 0 & 0 & 0 \\ 0 & 0 & r^2 & 0 & 0 & 0 \\ 0 & 0 & 0 & r^2\sin^2\theta &0 & 0 \\  0 & 0 & 0 &0 & r^2\sin^2\theta\sin^2\varphi & 0 \\  0 & 0 & 0 &0 &  0 & r^2\sin^2\theta\sin^2\varphi\sin^2\psi \end{array} \right)}

の仮定のもとで上と同様の解析をしてみると、Einstein方程式から  f に対して条件

 rf'+3f-3=0 \\  r^2 f'' +6r f'+6f-6=0

が課されます。これらを組み合わせた微分方程式

 r^2 f'' +12(1 -f)=0

の一般解は

 \displaystyle{f(r)=1-\frac{a}{r^3}-br^4}

で与えられます。6次元Schwarzschild解は  \displaystyle{f(r)=1-a/r^3} の場合に対応します。

一般の n 次元の場合は、これまでの結果から予想できると思います。

 

キーワード:Riemann幾何、一般相対論、Schwarzschild解、Maxima

プライバシーポリシー